home *** CD-ROM | disk | FTP | other *** search
/ No Fragments Archive 12: Textmags & Docs / nf_archive_12.iso / MAGS / SOURCES / ATARI_SRC.ZIP / atari source / AHDI / SYQUEST / SQHDX / PACKET.S < prev    next >
Encoding:
Text File  |  2001-02-09  |  8.9 KB  |  320 lines
  1. * ---------------- Low-level driver ----------------
  2. *----- Hardware:
  3. dmactlr        equ    $ffff8604    ; address of DMA controller
  4. wdc        equ    $0        ; DMA controller port
  5. wdl        equ    $2        ; DMA controller
  6. wdcwdl        equ    wdc        ; used for long writes
  7.  
  8. dmahi        equ    $ffff8609    ; DMA address - high byte
  9. dmamid        equ    dmahi+2        ;           - middle byte
  10. dmalow        equ    dmamid+2    ;          - low byte
  11.  
  12. gpip        equ    $fffffa01
  13.  
  14.  
  15. *----- Tunable:
  16. ltimeout    equ    450000        ; long-timeout (3 S)
  17. stimeout    equ    15000        ; short-timeout (100 mS)
  18.  
  19. SIXBYTE        equ    4        ; length of command - 2
  20. cmdwdl:        dc.w    0        ; wdl value for sending command byte
  21. datawdl:    dc.w    0        ; wdl value for sending data byte
  22. ctrlwdl:    dc.w    0        ; wdl value for sending control byte
  23. cmdblk:        dcb.b    6,0        ; command block
  24. ncmd:        dc.b    0        ; flag for continous command
  25. .even
  26.  
  27. *+
  28. * _docmd() - send a given packet to the controller and wait till command
  29. *         is completed
  30. *       - there is a 2nd entry point at _scmd if NO DMA is involved
  31. * 
  32. * Synopsis:    WORD _docmd(buf_addr)    /* Entry point for command with DMA */
  33. *         LONG buf_addr;        4(sp).l
  34. *
  35. *        WORD _scmd()        /* Entry point for command w/o DMA */
  36. *
  37. * Assumed:    d1.w = command block length - 2
  38. *        d2.l - if MSB set = writing to DMA
  39. *               if MSB not set = reading from DMA
  40. *             - d2.w = # sectors of DMA involved
  41. *
  42. *-
  43.     .globl    _docmd
  44.     .globl    _shdc
  45.     .globl    _shdc1
  46. _docmd:    st    flock            ; lock FIFO (DMA channel)
  47.     move.b    7(sp),dmalow        ; else set DMA to point to
  48.     move.b    6(sp),dmamid        ;      buffer for transfer
  49.     move.b    5(sp),dmahi
  50.     movea.l    #dmactlr,a0        ; a0 = address of DMA controller
  51.     
  52.     moveq    #31,d0            ; d0 = bit number to be tested
  53.     bclr.l    d0,d2            ; reading from DMA?
  54.     beq    rdma            ; if so, go set DMA to read state
  55.                     ; direction of data flow: ST -> DMA
  56.     move.w    #$188,cmdwdl        ; wdl for command byte = $188
  57.     move.w    #$18a,datawdl        ; wdl for data byte = $18a
  58.     move.w    #$100,ctrlwdl        ; wdl for control byte = $100
  59.     move.w    #$90,wdl(a0)        ; reset DMA controller
  60.     move.w    #$190,wdl(a0)        ;     and leave in write state
  61.     move.w    d2,wdc(a0)        ; # of 512 bytes sectors
  62.     move.w    #$18a,wdl(a0)        ; point back to parameter port
  63.     bra    _shdc1            ; go on to send command block
  64.                     ; direction of data flow: DMA -> ST
  65. rdma:    move.w    #$88,cmdwdl        ; wdl for command byte = $88
  66.     move.w    #$8a,datawdl        ; wdl for data byte = $8a
  67.     move.w    #$00,ctrlwdl        ; wdl for control byte = $00
  68.     move.w    #$190,wdl(a0)        ; reset DMA controller
  69.     move.w    #$90,wdl(a0)        ;     and leave in read state
  70.     move.w    d2,wdc(a0)        ; # of 512 bytes sectors
  71.     move.w    #$8a,wdl(a0)        ; point back to parameter port
  72.     bra    _shdc1            ; go on to send command block
  73.  
  74. _shdc:    st    flock            ; lock FIFO (DMA channel)
  75.     move.w    #$88,cmdwdl        ; wdl for command byte = $88
  76.     move.w    #$8a,datawdl        ; wdl for data byte = $8a
  77.     move.w    #$8a,ctrlwdl        ; wdl for control byte = $8a
  78.     movea.l    #dmactlr,a0        ; a0 = address of DMA controller
  79.  
  80. _shdc1:    lea    cmdblk,a1        ; a1 = ptr to command block
  81.     move.w    cmdwdl,wdl(a0)        ; sending a command
  82.     clr.w    d0            ; clear d0
  83.     move.w    #SIXBYTE,d1        ; length of command 
  84. shdc2:    move.b    (a1)+,d0        ; d0.b = command byte to be sent
  85.     swap    d0            ; hi word of d0.l = command byte
  86.     move.w    datawdl,d0        ; d0.w = next byte will be an operand
  87.     move.l    d0,wdcwdl(a0)        ; write command to DMA
  88.     bsr    _qdone            ; wait a little while
  89.     bmi    dcmd            ; if timeout, done with timeout error
  90.     dbra    d1,shdc2        ; do until all command bytes are sent
  91.                     ; now send the control byte
  92.     move.b    (a1),d0            ; last byte from command byte
  93.     swap    d0            ; hi word of d0.l = command byte
  94.     move.w    ctrlwdl,d0        ; d0.w = wdl value for contro byte
  95.     move.l    d0,wdcwdl(a0)        ; write to controller
  96.                     ; wait for command completion
  97.     bsr    _fdone            ; wait for operation complete
  98. dlcmd:    move.l    _hz_200,d1        ; delay 2 ticks for completion byte
  99.     addq.l    #2,d1
  100. wait:    cmp.l    _hz_200,d1        
  101.     bcc    wait
  102.     tst.w    d0            ; was it successful?
  103.     bmi    dcmd            ; if timed out, return
  104.  
  105.     move.w    datawdl,wdl(a0)        ; else point back to parameter port
  106.     move.w    wdc(a0),d0        ; get the result
  107.     andi.w    #$00ff,d0        ; (clean it up), if non-zero should
  108.                     ; do a ReadSense command to learn more
  109.     bne    dcmd            ; if not successful, return
  110.  
  111.     tst.b    ncmd            ; else, another command right after?
  112.     beq    dcmd            ; if not, return normally
  113.     tst.w    d0
  114.     rts                ; else, return now
  115.  
  116. dcmd:    move.w    #$80,wdl(a0)        ; Landon's code seems to presume we
  117.     nop                ;  put this back to $80
  118.     clr    flock            ; NOW, signal that we are done
  119.     tst.w    d0            ; set condition code to reveal result
  120.     rts
  121.  
  122.  
  123.  
  124. *+
  125. * LONG _qdone() - Wait for command byte handshake
  126. * LONG _fdone() - Wait for operation complete
  127. * Passed:    nothing
  128. *
  129. * Returns:    EQ: no timeout
  130. *        MI: timeout condition
  131. *
  132. * Uses:        D0
  133. *
  134. * each pass through the loop takes 6.75 uS
  135. *-
  136. _fdone:    move.l    #ltimeout,tocount
  137.     bra    qd1
  138.  
  139. _qdone:
  140.     move.l    #stimeout,tocount
  141.  
  142. qd1:    subq.l    #1,tocount        ; drop timeout count
  143.     bmi    qdq            ; (i give up, return NE)
  144.     btst    #5,gpip            ; interrupt?
  145.     bne    qd1            ; (not yet)
  146.  
  147.     moveq    #0,d0            ; return EQ (no timeout)
  148.     rts
  149.  
  150. qdq:    moveq    #-1,d0
  151.     rts
  152.  
  153.  
  154.  
  155. *-
  156. * clrcmdblk()
  157. *
  158. * Clear the command block for the driver call
  159. *+
  160. clrcmdblk:
  161.     lea    cmdblk,a0        ; a0 = ptr to command block
  162.     move.l    #0,(a0)+
  163.     move.w    #0,(a0)
  164.     rts
  165.  
  166.  
  167.  
  168. *-
  169. * _hread(sectno, count, buf, dev)
  170. * LONG sectno;         4(sp)
  171. * WORD count;         8(sp)
  172. * LONG buf;        $a(sp)    $b=high, $c=mid, $d=low
  173. * WORD dev;        $e(sp)
  174. *
  175. * Returns:    -1 on timeout
  176. *        0 on success
  177. *        nonzero on error
  178. *
  179. *-
  180. READ    equ    $8
  181.     .globl    _hread
  182. _hread:    bsr    clrcmdblk        ; clear the command block
  183.     lea    cmdblk,a0        ; a0 = ptr to command block
  184.     move.w    $e(sp),d0        ; get unit number
  185.     lsl.b    #5,d0            ; shift it into place
  186.     ori.b    #READ,d0        ; dev# + READ command
  187.     move.b    d0,(a0)+        ; 1st command byte = dev# + READ
  188.     move.b    $5(sp),(a0)+        ; MSB sector#
  189.     move.b    $6(sp),(a0)+        ; MidSB sector#
  190.     move.b    $7(sp),(a0)+        ; LSB sector#
  191.     move.b    $9(sp),(a0)+        ; transfer length (in sectors)
  192.     moveq    #0,d2            ; clear d2.l
  193.     move.w    $8(sp),d2        ; # sectors to read
  194.     sf    ncmd
  195.     move.l    $a(sp),-(sp)        ; buffer to transfer data to
  196.     bsr    _docmd            ; just do it
  197.     addq    #4,sp            ; cleanup stack
  198.     rts
  199.  
  200.  
  201. *-
  202. * _hwrite(sectno, count, buf, dev)
  203. * LONG sectno;         4(sp)
  204. * WORD count;         8(sp)
  205. * LONG buf;        $a(sp)    $b=high, $c=mid, $d=low
  206. * WORD dev;        $e(sp)
  207. *
  208. *-
  209. WRITE    equ    $a
  210.     .globl    _hwrite
  211. _hwrite:
  212.     bsr    clrcmdblk        ; clear the command block
  213.     lea    cmdblk,a0        ; a0 = ptr to command block
  214.     move.w    $e(sp),d0        ; get unit number
  215.     lsl.b    #5,d0            ; shift it into place
  216.     ori.b    #WRITE,d0        ; dev# + WRITE command
  217.     move.b    d0,(a0)+        ; 1st command block = dev# + WRITE
  218.     move.b    $5(sp),(a0)+        ; MSB sector#
  219.     move.b    $6(sp),(a0)+        ; MidSB sector#
  220.     move.b    $7(sp),(a0)+        ; LSB sector#
  221.     move.b    $9(sp),(a0)+        ; transfer length (in sectors)
  222.     move.w    #31,d1            ; bit # to be set
  223.     moveq    #0,d2            ; clear d2.l
  224.     bset.l    d1,d2            ; set direction bit: ST -> DMA
  225.     move.w    $8(sp),d2        ; # sectors to write
  226.     sf    ncmd
  227.     move.l    $a(sp),-(sp)        ; buffer to transfer data to
  228.     bsr    _docmd            ; just do it
  229.     addq    #4,sp            ; cleanup stack
  230.     rts
  231.  
  232.  
  233.  
  234. *+
  235. *  _inquiry - get device-specific parameters
  236. *
  237. *    Synopsis:    LONG _inquiry(physunit#, parms)
  238. *        WORD physunit#;            4(sp).W
  239. *        char *parms;            6(sp).L
  240. *
  241. *-
  242. INQUIRE    equ    $12
  243.     .globl    _inquiry
  244. _inquiry:
  245.     bsr    clrcmdblk        ; clear the command block
  246.     lea    cmdblk,a0        ; a0 = ptr to command block
  247.     move.w    4(sp),d0        ; d0 = physical unit #
  248.     lsl.b    #5,d0            ; shift it into place
  249.     ori.b    #INQUIRE,d0        ; physunit# + Inquiry command
  250.     move.b    d0,(a0)            ; byte 0 = dev# + opcode
  251.     move.b    #$10,4(a0)        ; byte 4 = allocation length
  252.     moveq    #1,d2            ; 1 sector of dma
  253.     move.l    6(sp),-(sp)        ; -> parameter block address
  254.     bsr    _docmd            ; just do it
  255.     addq    #4,sp            ; cleanup stack
  256.     rts
  257.  
  258.  
  259.  
  260. *+
  261. *  _rq_sense - get sense data from target
  262. *
  263. *    Synopsis:    LONG _rq_sense(physunit#, data)
  264. *        WORD physunit#;            4(sp).W
  265. *        char data[];            6(sp).L
  266. *
  267. *-
  268. RQSENSE    equ    $3
  269.     .globl    _rq_sense
  270. _rq_sense:
  271.     bsr    clrcmdblk        ; clear the command block
  272.     lea    cmdblk,a0        ; a0 = ptr to command block
  273.     move.w    4(sp),d0        ; d0 = (physunit# << 5) << 16
  274.     lsl.b    #5,d0            ; shift it into place
  275.     ori.b    #RQSENSE,d0        ; physunit# + Request Sense command
  276.     move.b    d0,(a0)            ; byte 0 = dev# + opcode
  277.     moveq    #1,d2            ; 1 sector of dma
  278.     move.w    d3,-(sp)        ; save d3
  279.     st    ncmd            ; don't clear flock when return
  280.     move.l    8(sp),-(sp)        ; -> parameter block address
  281.     bsr    _docmd            ; just do it
  282.     addq    #4,sp            ; cleanup stack
  283.     bne    rqsr            ; if unsuccessful, return
  284.     move.w    #1,d3            ; do the command 2 more times
  285. loop2x:    bsr    _shdc1
  286.     bne    rqsr
  287.     dbra    d3,loop2x
  288.     sf    ncmd            ; clear flock when return
  289.     bsr    _shdc1
  290. rqsr:    move.w    (sp)+,d3        ; restore d3
  291.     sf    ncmd            ; reset flag
  292.     rts
  293.  
  294.  
  295.  
  296. *+
  297. *  testunit - Test Unit Ready
  298. *
  299. *    Synopsis:    LONG testunit(dev)
  300. *        WORD dev;        4(sp).W
  301. *
  302. *-
  303. TSTUNIT    equ    $3
  304.     .globl    testunit
  305. testunit:
  306.     bsr    clrcmdblk        ; clear the command block
  307.     lea    cmdblk,a0        ; a0 = ptr to command block
  308.     move.w    4(sp),d0        ; d0 = (physunit# << 5) << 16
  309.     lsl.b    #5,d0            ; shift it into place
  310.     ori.b    #TSTUNIT,d0        ; physunit# + Test Unit command
  311.     move.b    d0,(a0)            ; byte 0 = dev# + opcode
  312.     sf    ncmd
  313.     bsr    _shdc            ; just do it
  314.     rts
  315.  
  316.  
  317.  
  318.  
  319.  
  320.